"Filed out from GNU Smalltalk version 2.0k on 2-Mar-2003  0:33:47"!

!BLOX.BLOXBrowser.NamespaceBrowser methodsFor: 'class list blue button menu'!
fileOutNamespace: listView 
    "File out a description of the currently selected namespace"

    | oldCurrent className fileName stream |
    curNamespace isNil ifTrue: [^listView beep].
    fileName := self fileoutDir , self fileoutName , '.st'.
    fileName := Prompter 
		saveFileName: 'File out namespace'
		default: fileName
		in: listView.
    fileName isNil ifTrue: [^self].
    stream := FileStream open: fileName mode: FileStream write.
    byCategory 
	ifFalse: 
	    [curNamespace superspace isNil 
		ifFalse: 
		    [stream
			nextPutAll: (curNamespace superspace nameIn: Smalltalk);
			nextPutAll: ' addSubspace: #';
			nextPutAll: curNamespace name;
			nextPutAll: '!';
			nl;
			nextPutAll: 'Namespace current: ';
			nextPutAll: (curNamespace nameIn: Smalltalk);
			nextPutAll: '!';
			nl;
			nl]
		ifTrue: 
		    [stream
			nextPutAll: 'Namespace current: (RootNamespace new: #';
			nextPutAll: (curNamespace nameIn: Smalltalk);
			nextPutAll: ')!';
			nl;
			nl].
	    oldCurrent := Namespace current.
	    Namespace current: curNamespace].
    classList do: 
	    [:each | 
	    (each trimSeparators includes: $() 
		ifFalse: [(shownClasses at: each) fileOutOn: stream]].
    byCategory 
	ifFalse: 
	    [Namespace current: oldCurrent.
	    stream
		nextPutAll: 'Namespace current: Smalltalk!';
		nl].
    stream close.
    self setFileoutDirFromFile: fileName! !