[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: ams-pers-scheme-0.01
From: |
Thien-Thi Nguyen |
Subject: |
Re: ams-pers-scheme-0.01 |
Date: |
Wed, 26 Dec 2001 16:35:28 -0800 |
fyi, example configure.in usage:
AC_GUILE_MODULE_CHECK(ice9_common_list,(ice-9 common-list),
(lambda () 0), `abc' clears blurfl)
AC_GUILE_MODULE_AVAILABLE(ice9_cl2,(ice-9 common-listx))
AC_GUILE_MODULE_REQUIRED(ice-9 common-listx)
the latter two test the failure case.
also, below are the updated AC_DEFUNs (now 3).
thi
___________________________________________________________
# AC_GUILE_MODULE_CHECK(var,module,featuretest)
# - var is a shell variable name
# - module is a list of symbols, like: (ice-9 common-list)
# - featuretest is a thunk, like: (lambda () BODY ...)
# use "#t" for BODY for modules whose availability is the feature
#
AC_DEFUN([AC_GUILE_MODULE_CHECK],
[AC_MSG_CHECKING([$2 $4])
$1=no
echo '(use-modules $2) (exit ($3))' > conftest
guile -s conftest > /dev/null 2>&1 && $1=yes
rm -f conftest
AC_MSG_RESULT($[$1])
])
# AC_GUILE_MODULE_AVAILABLE(var,module)
# - var is a shell variable name
# - module is a list of symbols, like: (ice-9 common-list)
#
AC_DEFUN([AC_GUILE_MODULE_AVAILABLE],
[AC_GUILE_MODULE_CHECK($1,$2,(lambda () 0),availability)
])
# AC_GUILE_MODULE_REQUIRED(modulesyms)
# - modulesyms is a list of symbols, WITHOUT the surrounding parens
#
AC_DEFUN([AC_GUILE_MODULE_REQUIRED],
[AC_GUILE_MODULE_AVAILABLE(ac_guile_module_required, ($1))
if test "$ac_guile_module_required" = "no" ; then
AC_MSG_ERROR([required guile module not found: ($1)])
fi
])