[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
01/03: home-services: Add Mcron.
|
From: |
guix-commits |
|
Subject: |
01/03: home-services: Add Mcron. |
|
Date: |
Mon, 13 Sep 2021 16:01:40 -0400 (EDT) |
wigust pushed a commit to branch wip-guix-home
in repository guix.
commit bac597cc968a4fd6c1bf41cffebf921e8581ca72
Author: Andrew Tropin <andrew@trop.in>
AuthorDate: Fri Sep 10 09:26:33 2021 +0300
home-services: Add Mcron.
* gnu/home-services/mcron.scm: New file.
* gnu/local.mk: Add this.
* doc/guix.texi: Add documentation about Mcron Home Service.
Signed-off-by: Oleg Pykhalov <go.wigust@gmail.com>
---
doc/guix.texi | 39 +++++++++++++--
gnu/home-services/mcron.scm | 115 ++++++++++++++++++++++++++++++++++++++++++++
gnu/local.mk | 1 +
3 files changed, 151 insertions(+), 4 deletions(-)
diff --git a/doc/guix.texi b/doc/guix.texi
index e546fcc..419d942 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -16090,9 +16090,9 @@ This is the type of the @code{mcron} service, whose
value is an
@code{mcron-configuration} object.
This service type can be the target of a service extension that provides
-it additional job specifications (@pxref{Service Composition}). In
-other words, it is possible to define services that provide additional
-mcron jobs to run.
+additional job specifications (@pxref{Service Composition}). In other
+words, it is possible to define services that provide additional mcron
+jobs to run.
@end defvr
@deftp {Data Type} mcron-configuration
@@ -35685,7 +35685,38 @@ for example).
@cindex mcron
@cindex scheduling jobs
-mcron info here
+The @code{(gnu home-services mcron)} module provides an interface to
+GNU@tie{}mcron, a daemon to run jobs at scheduled times (@pxref{Top,,,
+mcron, GNU@tie{}mcron}). The information about system's mcron is
+applicable here (@pxref{Scheduled Job Execution}), the only difference
+for home services is that they have to be declared in a
+@code{home-envirnoment} record instead of an @code{operating-system}
+record.
+
+@defvr {Scheme Variable} home-mcron-service-type
+This is the type of the @code{mcron} home service, whose value is an
+@code{home-mcron-configuration} object. It allows to manage scheduled
+tasks.
+
+This service type can be the target of a service extension that provides
+additional job specifications (@pxref{Service Composition}). In other
+words, it is possible to define services that provide additional mcron
+jobs to run.
+@end defvr
+
+@deftp {Data Type} home-mcron-configuration
+Data type representing the configuration of mcron.
+
+@table @asis
+@item @code{mcron} (default: @var{mcron})
+The mcron package to use.
+
+@item @code{jobs}
+This is a list of gexps (@pxref{G-Expressions}), where each gexp
+corresponds to an mcron job specification (@pxref{Syntax, mcron job
+specifications,, mcron, GNU@tie{}mcron}).
+@end table
+@end deftp
@node Shepherd Home Service
@subsection Managing User's Daemons
diff --git a/gnu/home-services/mcron.scm b/gnu/home-services/mcron.scm
new file mode 100644
index 0000000..fdfde17
--- /dev/null
+++ b/gnu/home-services/mcron.scm
@@ -0,0 +1,115 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2021 Andrew Tropin <andrew@trop.in>
+;;; Copyright © 2021 Xinglu Chen <public@yoctocell.xyz>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu home-services mcron)
+ #:use-module (gnu packages guile-xyz)
+ #:use-module (gnu home-services)
+ #:use-module (gnu home-services shepherd)
+ #:use-module (gnu services shepherd)
+ #:use-module (guix records)
+ #:use-module (guix gexp)
+ #:use-module (srfi srfi-1)
+ #:use-module (ice-9 match)
+
+ #:export (home-mcron-configuration
+ home-mcron-service-type))
+
+;;; Commentary:
+;;
+;; Service for the GNU mcron cron job manager.
+;;
+;; Example configuration, the first job runs mbsync once every ten
+;; minutes, the second one writes "Mcron service" to ~/mcron-file once
+;; every minute.
+;;
+;; (service home-mcron-service-type
+;; (home-mcron-configuration
+;; (jobs (list #~(job '(next-minute
+;; (range 0 60 10))
+;; (lambda ()
+;; (system* "mbsync" "--all")))
+;; #~(job next-minute-from
+;; (lambda ()
+;; (call-with-output-file (string-append
(getenv "HOME")
+;;
"/mcron-file")
+;; (lambda (port)
+;; (display "Mcron service" port)))))))))
+;;
+;;; Code:
+
+(define-record-type* <home-mcron-configuration> home-mcron-configuration
+ make-home-mcron-configuration
+ home-mcron-configuration?
+ (package home-mcron-configuration-package ; package
+ (default mcron))
+ (jobs home-mcron-configuration-jobs ; list of jobs
+ (default '())))
+
+(define job-files (@@ (gnu services mcron) job-files))
+(define shepherd-schedule-action
+ (@@ (gnu services mcron) shepherd-schedule-action))
+
+(define home-mcron-shepherd-services
+ (match-lambda
+ (($ <home-mcron-configuration> mcron '()) ; no jobs to run
+ '())
+ (($ <home-mcron-configuration> mcron jobs)
+ (let ((files (job-files mcron jobs)))
+ (list (shepherd-service
+ (documentation "User cron jobs.")
+ (provision '(mcron))
+ (modules `((srfi srfi-1)
+ (srfi srfi-26)
+ (ice-9 popen) ; for the 'schedule' action
+ (ice-9 rdelim)
+ (ice-9 match)
+ ,@%default-modules))
+ (start #~(make-forkexec-constructor
+ (list #$(file-append mcron "/bin/mcron") #$@files)
+ #:log-file (string-append
+ (or (getenv "XDG_LOG_HOME")
+ (format #f "~a/.local/var/log"
+ (getenv "HOME")))
+ "/mcron.log")))
+ (stop #~(make-kill-destructor))
+ (actions
+ (list (shepherd-schedule-action mcron files)))))))))
+
+(define home-mcron-profile (compose list home-mcron-configuration-package))
+
+(define (home-mcron-extend config jobs)
+ (home-mcron-configuration
+ (inherit config)
+ (jobs (append (home-mcron-configuration-jobs config)
+ jobs))))
+
+(define home-mcron-service-type
+ (service-type (name 'home-mcron)
+ (extensions
+ (list (service-extension
+ home-shepherd-service-type
+ home-mcron-shepherd-services)
+ (service-extension
+ home-profile-service-type
+ home-mcron-profile)))
+ (compose concatenate)
+ (extend home-mcron-extend)
+ (default-value (home-mcron-configuration))
+ (description
+ "Install and configure the GNU mcron cron job manager.")))
diff --git a/gnu/local.mk b/gnu/local.mk
index 31ad1a4..8212bc5 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -80,6 +80,7 @@ GNU_SYSTEM_MODULES = \
%D%/home-services/configuration.scm \
%D%/home-services/shells.scm \
%D%/home-services/shepherd.scm \
+ %D%/home-services/mcron.scm \
%D%/home-services/utils.scm \
%D%/home-services/xdg.scm \
%D%/image.scm \