[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
bug#27296: [PATCH 14/35] build-system: Add 'texlive-build-system'.
From: |
Ricardo Wurmus |
Subject: |
bug#27296: [PATCH 14/35] build-system: Add 'texlive-build-system'. |
Date: |
Fri, 9 Jun 2017 12:45:38 +0200 |
* guix/build-system/texlive.scm: New file.
* guix/build/texlive-build-system.scm: New file.
* Makefile.am (MODULES): Add them.
* doc/guix.texi (Build Systems): Document it.
* gnu/packages/tex.scm (%texlive-tag, %texlive-revision): Remove variables.
(texlife-ref): Remove procedure.
---
Makefile.am | 3 +
doc/guix.texi | 19 +++++
gnu/packages/tex.scm | 14 +--
guix/build-system/texlive.scm | 165 ++++++++++++++++++++++++++++++++++++
guix/build/texlive-build-system.scm | 89 +++++++++++++++++++
5 files changed, 277 insertions(+), 13 deletions(-)
create mode 100644 guix/build-system/texlive.scm
create mode 100644 guix/build/texlive-build-system.scm
diff --git a/Makefile.am b/Makefile.am
index 3925f3e2d..c10dffb44 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -6,6 +6,7 @@
# Copyright © 2016, 2017 Mark H Weaver <address@hidden>
# Copyright © 2017 Mathieu Othacehe <address@hidden>
# Copyright © 2017 Leo Famulari <address@hidden>
+# Copyright © 2017 Ricardo Wurmus <address@hidden>
#
# This file is part of GNU Guix.
#
@@ -87,6 +88,7 @@ MODULES = \
guix/build-system/waf.scm \
guix/build-system/r.scm \
guix/build-system/ruby.scm \
+ guix/build-system/texlive.scm \
guix/build-system/trivial.scm \
guix/ftp-client.scm \
guix/http-client.scm \
@@ -114,6 +116,7 @@ MODULES = \
guix/build/ocaml-build-system.scm \
guix/build/r-build-system.scm \
guix/build/ruby-build-system.scm \
+ guix/build/texlive-build-system.scm \
guix/build/waf-build-system.scm \
guix/build/haskell-build-system.scm \
guix/build/store-copy.scm \
diff --git a/doc/guix.texi b/doc/guix.texi
index 87aaae854..f1b2d4612 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -3575,6 +3575,25 @@ are run after installation using the R function
@code{tools::testInstalledPackage}.
@end defvr
address@hidden {Scheme Variable} texlive-build-system
+This variable is exported by @code{(guix build-system texlive)}. It is
+used to build TeX packages in batch mode with a specified engine. The
+build system sets the @code{TEXINPUTS} variable to find all TeX source
+files in the inputs.
+
+By default it runs @code{luatex} on all files ending on @code{ins}. A
+different engine and format can be specified with the
address@hidden:tex-format} argument. Different build targets can be specified
+with the @code{#:build-targets} argument, which expects a list of file
+names. The build system adds only @code{texlive-bin} and
address@hidden (both from @code{(gnu packages tex}) to the
+inputs. Both can be overridden with the arguments @code{#:texlive-bin}
+and @code{#:texlive-latex-base}, respectively.
+
+The @code{#:tex-directory} tells the build system where to install the
+built files under the texmf tree.
address@hidden defvr
+
@defvr {Scheme Variable} ruby-build-system
This variable is exported by @code{(guix build-system ruby)}. It
implements the RubyGems build procedure used by Ruby packages, which
diff --git a/gnu/packages/tex.scm b/gnu/packages/tex.scm
index 9ff0f234e..5cb4ec6ab 100644
--- a/gnu/packages/tex.scm
+++ b/gnu/packages/tex.scm
@@ -30,6 +30,7 @@
#:use-module (guix build-system gnu)
#:use-module (guix build-system perl)
#:use-module (guix build-system trivial)
+ #:use-module (guix build-system texlive)
#:use-module (guix utils)
#:use-module (guix git-download)
#:use-module (guix svn-download)
@@ -180,10 +181,6 @@ This package contains the binaries.")
(license (license:fsf-free "https://www.tug.org/texlive/copying.html";))
(home-page "https://www.tug.org/texlive/";)))
-;; These variables specify the SVN tag and the matching SVN revision.
-(define %texlive-tag "texlive-2017.0")
-(define %texlive-revision 44445)
-
(define-public texlive-dvips
(package
(name "texlive-dvips")
@@ -689,15 +686,6 @@ TeXbook, together with various supporting files (some also
discussed in the
book).")
(license license:knuth)))
-(define (texlive-ref component id)
- "Return a <svn-reference> object for the package ID, which is part of the
-given Texlive COMPONENT."
- (svn-reference
- (url (string-append "svn://www.tug.org/texlive/tags/"
- %texlive-tag "/Master/texmf-dist/"
- "source/" component "/" id))
- (revision %texlive-revision)))
-
(define-public texlive-latex-base
(let ((texlive-dir
(lambda (dir hash)
diff --git a/guix/build-system/texlive.scm b/guix/build-system/texlive.scm
new file mode 100644
index 000000000..6a0d48b4e
--- /dev/null
+++ b/guix/build-system/texlive.scm
@@ -0,0 +1,165 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Ricardo Wurmus <address@hidden>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system texlive)
+ #:use-module (guix store)
+ #:use-module (guix utils)
+ #:use-module (guix packages)
+ #:use-module (guix derivations)
+ #:use-module (guix search-paths)
+ #:use-module (guix build-system)
+ #:use-module (guix build-system gnu)
+ #:use-module (guix svn-download)
+ #:use-module (ice-9 match)
+ #:export (%texlive-build-system-modules
+ texlive-build
+ texlive-build-system
+ texlive-ref
+ %texlive-tag
+ %texlive-revision))
+
+;; Commentary:
+;;
+;; Standard build procedure for Texlive packages.
+;;
+;; Code:
+
+;; These variables specify the SVN tag and the matching SVN revision.
+(define %texlive-tag "texlive-2017.0")
+(define %texlive-revision 44445)
+
+(define (texlive-ref component id)
+ "Return a <svn-reference> object for the package ID, which is part of the
+given Texlive COMPONENT."
+ (svn-reference
+ (url (string-append "svn://www.tug.org/texlive/tags/"
+ %texlive-tag "/Master/texmf-dist/"
+ "source/" component "/" id))
+ (revision %texlive-revision)))
+
+(define %texlive-build-system-modules
+ ;; Build-side modules imported by default.
+ `((guix build texlive-build-system)
+ ,@%gnu-build-system-modules))
+
+(define (default-texlive-bin)
+ "Return the default texlive-bin package."
+ ;; Lazily resolve the binding to avoid a circular dependency.
+ (let ((tex-mod (resolve-interface '(gnu packages tex))))
+ (module-ref tex-mod 'texlive-bin)))
+
+(define (default-texlive-latex-base)
+ "Return the default texlive-latex-base package."
+ ;; Lazily resolve the binding to avoid a circular dependency.
+ (let ((tex-mod (resolve-interface '(gnu packages tex))))
+ (module-ref tex-mod 'texlive-latex-base)))
+
+(define* (lower name
+ #:key
+ source inputs native-inputs outputs
+ system target
+ (texlive-latex-base (default-texlive-latex-base))
+ (texlive-bin (default-texlive-bin))
+ #:allow-other-keys
+ #:rest arguments)
+ "Return a bag for NAME."
+ (define private-keywords
+ '(#:source #:target #:inputs #:native-inputs
+ #:texlive-latex-base #:texlive-bin))
+
+ (and (not target) ;XXX: no cross-compilation
+ (bag
+ (name name)
+ (system system)
+ (host-inputs `(,@(if source
+ `(("source" ,source))
+ '())
+ ,@inputs
+
+ ;; Keep the standard inputs of 'gnu-build-system'.
+ ,@(standard-packages)))
+ (build-inputs `(("texlive-bin" ,texlive-bin)
+ ("texlive-latex-base" ,texlive-latex-base)
+ ,@native-inputs))
+ (outputs outputs)
+ (build texlive-build)
+ (arguments (strip-keyword-arguments private-keywords arguments)))))
+
+(define* (texlive-build store name inputs
+ #:key
+ (tests? #f)
+ tex-directory
+ (build-targets #f)
+ (tex-format "luatex")
+ (phases '(@ (guix build texlive-build-system)
+ %standard-phases))
+ (outputs '("out"))
+ (search-paths '())
+ (system (%current-system))
+ (guile #f)
+ (substitutable? #t)
+ (imported-modules %texlive-build-system-modules)
+ (modules '((guix build texlive-build-system)
+ (guix build utils))))
+ "Build SOURCE with INPUTS."
+ (define builder
+ `(begin
+ (use-modules ,@modules)
+ (texlive-build #:name ,name
+ #:source ,(match (assoc-ref inputs "source")
+ (((? derivation? source))
+ (derivation->output-path source))
+ ((source)
+ source)
+ (source
+ source))
+ #:tex-directory ,tex-directory
+ #:build-targets ,build-targets
+ #:tex-format ,tex-format
+ #:system ,system
+ #:tests? ,tests?
+ #:phases ,phases
+ #:outputs %outputs
+ #:search-paths ',(map search-path-specification->sexp
+ search-paths)
+ #:inputs %build-inputs)))
+
+ (define guile-for-build
+ (match guile
+ ((? package?)
+ (package-derivation store guile system #:graft? #f))
+ (#f ; the default
+ (let* ((distro (resolve-interface '(gnu packages commencement)))
+ (guile (module-ref distro 'guile-final)))
+ (package-derivation store guile system #:graft? #f)))))
+
+ (build-expression->derivation store name builder
+ #:inputs inputs
+ #:system system
+ #:modules imported-modules
+ #:outputs outputs
+ #:guile-for-build guile-for-build
+ #:substitutable? substitutable?))
+
+(define texlive-build-system
+ (build-system
+ (name 'texlive)
+ (description "The build system for Texlive packages")
+ (lower lower)))
+
+;;; texlive.scm ends here
diff --git a/guix/build/texlive-build-system.scm
b/guix/build/texlive-build-system.scm
new file mode 100644
index 000000000..af6fa82b4
--- /dev/null
+++ b/guix/build/texlive-build-system.scm
@@ -0,0 +1,89 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Ricardo Wurmus <address@hidden>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build texlive-build-system)
+ #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+ #:use-module (guix build utils)
+ #:use-module (ice-9 match)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-26)
+ #:export (%standard-phases
+ texlive-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the standard build procedure for Texlive packages.
+;;
+;; Code:
+
+(define (compile-with-latex format file)
+ (zero? (system* format
+ "-interaction=batchmode"
+ "-output-directory=build"
+ (string-append "&" format)
+ file)))
+
+(define* (build #:key inputs build-targets tex-format #:allow-other-keys)
+ ;; Find additional tex and sty files
+ (setenv "TEXINPUTS"
+ (string-append
+ (getcwd) ":" (getcwd) "/build:"
+ (string-join
+ (append-map (match-lambda
+ ((_ . dir)
+ (find-files dir
+ (lambda (_ stat)
+ (eq? 'directory (stat:type stat)))
+ #:directories? #t
+ #:stat stat)))
+ inputs)
+ ":")))
+ (setenv "TEXFORMATS"
+ (string-append (assoc-ref inputs "texlive-latex-base")
+ "/share/texmf-dist/web2c/"))
+ (setenv "LUAINPUTS"
+ (string-append (assoc-ref inputs "texlive-latex-base")
+ "/share/texmf-dist/tex/latex/base/"))
+ (mkdir "build")
+ (every (cut compile-with-latex tex-format <>)
+ (if build-targets build-targets
+ (find-files "." "\\.ins$"))))
+
+(define* (install #:key outputs tex-directory #:allow-other-keys)
+ (let* ((out (assoc-ref outputs "out"))
+ (target (string-append
+ out "/share/texmf-dist/tex/" tex-directory)))
+ (mkdir-p target)
+ (for-each delete-file (find-files "." "\\.(log|aux)$"))
+ (for-each (cut install-file <> target)
+ (find-files "build" ".*"))
+ #t))
+
+(define %standard-phases
+ (modify-phases gnu:%standard-phases
+ (delete 'configure)
+ (replace 'build build)
+ (delete 'check)
+ (replace 'install install)))
+
+(define* (texlive-build #:key inputs (phases %standard-phases)
+ #:allow-other-keys #:rest args)
+ "Build the given Texlive package, applying all of PHASES in order."
+ (apply gnu:gnu-build #:inputs inputs #:phases phases args))
+
+;;; texlive-build-system.scm ends here
--
2.12.2
- bug#27296: [PATCH 02/35] guix: Add common TeX and LaTeX licenses., (continued)
- bug#27296: [PATCH 15/35] gnu: Add texlive-latex-filecontents., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 10/35] gnu: Add texlive-fonts-knuth-lib., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 12/35] gnu: Add texlive-tex-plain., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 13/35] gnu: Add texlive-latex-base., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 16/35] gnu: Add texlive-generic-ifxetex., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 17/35] gnu: Add texlive-latex-fancyvrb., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 18/35] gnu: Add texlive-latex-graphics., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 19/35] gnu: Add texlive-latex-xcolor., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 20/35] gnu: Add texlive-latex-hyperref., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 14/35] build-system: Add 'texlive-build-system'.,
Ricardo Wurmus <=
- bug#27296: [PATCH 21/35] gnu: Add texlive-latex-oberdiek., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 22/35] gnu: Add texlive-latex-tools., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 23/35] gnu: Add texlive-latex-url., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 24/35] gnu: Add texlive-latex-l3kernel., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 25/35] gnu: Add texlive-latex-l3packages., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 26/35] gnu: Add texlive-latex-fontspec., Ricardo Wurmus, 2017/06/09
- bug#27296: [PATCH 27/35] gnu: Add texlive-luatex-lualibs., Ricardo Wurmus, 2017/06/09