[bug#51986] [PATCH] Add tlpui

[Nicolas Goaziou]

Hello,

The following patch adds TLPUI to "linux.scm".

Regards,
-- 
Nicolas Goaziou

>From 701601c421713157c13f6fd2c649b7e69fc079fd Mon Sep 17 00:00:00 2001
Message-Id: 
<701601c421713157c13f6fd2c649b7e69fc079fd.1637357746.git.mail@nicolasgoaziou.fr>
From: Nicolas Goaziou <mail@nicolasgoaziou.fr>
Date: Fri, 19 Nov 2021 22:35:25 +0100
Subject: [PATCH] gnu: Add tlpui.

* gnu/packages/linux.scm (tlpui): New variable.
---
 gnu/packages/linux.scm | 55 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index 1d005de1db..17a702c73e 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -6874,6 +6874,61 @@ (define-public tlp
     ;; rest is GPLv2+.
     (license (list license:gpl2+ license:gpl3+))))
 
+(define-public tlpui
+  (package
+    (name "tlpui")
+    (version "1.4.0")
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url "https://github.com/d4nj1/TLPUI";)
+             (commit (string-append "tlpui-" version))))
+       (file-name (git-file-name name version))
+       (sha256
+        (base32 "1sd380inkiq8mljnzjd8p69a6cnwv19v2793358v3ws1mr55x127"))))
+    (build-system python-build-system)
+    (arguments
+     `(#:tests? #false
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-setup.py
+           ;; Install data_files to $out/share instead of /usr/share.
+           (lambda _
+             (substitute* "setup.py"
+               (("/usr/") ""))))
+         (add-after 'unpack 'use-tlp-input
+           ;; Hard-code tlp-stat filename to avoid propagating "tlp".
+           (lambda* (#:key inputs #:allow-other-keys)
+             (let ((tlp-stat (string-append (assoc-ref inputs "tlp")
+                                            "/bin/tlp-stat")))
+               (substitute* '("tlpui/file.py"
+                              "tlpui/settingshelper.py"
+                              "tlpui/statui.py")
+                 (("which\\(\"tlp-stat\"\\)") (string-append "'" tlp-stat "'"))
+                 (("\"tlp-stat\"") (string-append "'" tlp-stat "'"))))))
+         (add-after 'install 'wrap-gi-python
+           (lambda* (#:key inputs outputs #:allow-other-keys)
+             (let ((out (assoc-ref outputs "out"))
+                   (gi-typelib-path (getenv "GI_TYPELIB_PATH")))
+               (wrap-program (string-append out "/bin/tlpui")
+                 `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path)))))))))
+    (native-inputs
+     `(("glib:bin" ,glib "bin")
+       ("gobject-introspection" ,gobject-introspection)))
+    (inputs
+     `(("gtk+" ,gtk+)
+       ("python-pygobject" ,python-pygobject)
+       ("tlp" ,tlp)))
+    (home-page "https://github.com/d4nj1/TLPUI";)
+    (synopsis "User interface for TLP written in Python")
+    (description
+     "The Python scripts in this project generate a GTK-UI to change
+TLP configuration files easily.  It has the aim to protect users from
+setting bad configuration and to deliver a basic overview of all the
+valid configuration values.")
+    (license license:gpl2+)))
+
 (define-public lshw
   (package
     (name "lshw")
-- 
2.34.0