[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: Eval keymapp in a macros
From: |
Stefan Monnier |
Subject: |
Re: Eval keymapp in a macros |
Date: |
Thu, 05 Aug 2021 09:53:16 -0400 |
User-agent: |
Gnus/5.13 (Gnus v5.13) Emacs/28.0.50 (gnu/linux) |
> (defmacro with-key-map (mapname &rest body)
> `(let ((map (eval-and-compile (if (string-match-p "-map$" (symbol-name
> ',mapname))
> (symbol-name ',mapname)
> (concat (symbol-name ',mapname) "-map"))))
> (defs '(,@body)))
> (dolist (def defs)
> (define-key (symbol-value (intern map))
> (if (vectorp (car def)) (car def)
> (read-kbd-macro (car def)))
> (cdr def)))))
Your `map` variable above has a misleading name since it won't hold
a map but a string (the name of the variable holding the map, so you
need the "double indirection" thought `intern` first and `symbol-value`
afterwards to get at the map).
(defun my--with-key-map (map defs)
(dolist (def defs)
(let ((key (car def)))
(define-key map
(if (vectorp key) key (read-kbd-macro key))
(cdr def)))))
(defmacro my-with-key-map (mapname &rest body)
`(my--with-key-map ,(if (string-match-p "-map\\'" (symbol-name mapname))
mapname
(intern (format "%s-map" mapname)))
',body))
Look ma! No `eval-and-compile` and no `symbol-value`.
Stefan
PS: Personally I'd recommend against the `string-match-p` dance, since
all it saves you is the typing of `-map` but in exchange it prevents
you from using your macro with keymaps that have a name that doesn't
end in `-map` and it "obfuscates" the code a little, preventing
things like ElDoc and Xref from understanding what's going on.
- Re: Eval keymapp in a macros, (continued)
- Re: Eval keymapp in a macros, Michael Heerdegen, 2021/08/03
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/04
- Re: Eval keymapp in a macros, Michael Heerdegen, 2021/08/04
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/05
- Re: Eval keymapp in a macros, Michael Heerdegen, 2021/08/05
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/12
- Re: Eval keymapp in a macros, Yuri Khan, 2021/08/04
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/04
- Re: Eval keymapp in a macros, Stefan Monnier, 2021/08/04
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/05
- Re: Eval keymapp in a macros,
Stefan Monnier <=
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/05
- Re: Eval keymapp in a macros, Stefan Monnier, 2021/08/05
- Re: Eval keymapp in a macros, Michael Heerdegen, 2021/08/06
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/12
- Re: Eval keymapp in a macros, Michael Heerdegen, 2021/08/04
- Re: Eval keymapp in a macros, Arthur Miller, 2021/08/05
- Re: Eval keymapp in a macros, Michael Heerdegen, 2021/08/05