# Maintainer: Lone_Wolf <lonewolf at xs4all dot nl>
# Contributor: Moritz Lipp <address@hidden>

_pkgbasename=libunwind
pkgname=lib32-libunwind
pkgver=1.2
pkgrel=0.2
pkgdesc="Portable and efficient C programming interface (API) to determine the call-chain of a program, multilib version"
arch=('x86_64')
url="http://www.nongnu.org/libunwind/"
license=('GPL')
depends=('libunwind' 'lib32-xz' 'gcc-multilib')
# makedepends=('texlive-core')

source=(http://download.savannah.gnu.org/releases/$_pkgbasename/$_pkgbasename-$pkgver.tar.gz)
md5sums=('eefcb5d7f78fdc8f1ed172a26ea4202f')

build() {
  cd $_pkgbasename-$pkgver
  
  export CC="gcc -m32"
  export CXX="g++ -m32"
  
  ./configure \
    --build=i686-pc-linux-gnu \
    --host=i686-pc-linux-gnu \
    --prefix=/usr \
    --libdir=/usr/lib32 \
    --disable-documentation # man pages are already included in libunwind package
  make
}

check() {
  cd "$srcdir/$_pkgbasename-$pkgver"
  make check || return 0
}

package() {
  cd $_pkgbasename-$pkgver
  make DESTDIR="$pkgdir/" install
  
  # this build only provides multilib binary for x86 on x86_64 , remove all includes for other architectures
  find $pkgdir/usr/include/*.h -not -name "*x86*" -exec rm -f {} \;
}

# vim:set ts=2 sw=2 et: