AX_CXX_GCC_ABI_DEMANGLE

[Neil Ferguson]

Hi, all -

I've attached a macro I just adapted from AC_CXX_RTTI by Luc Maisonobe.

AX_CXX_GCC_ABI_DEMANGLE discovers whether the compiler supports the GNU 
C++ ABI demangler via cxxabi.h and abi::__cxa_demangle().

License: same as the Autoconf tool suite itself - the GNU General Public 
License with the Autoconf special GPL Exception.

I don't subscribe to the ac-archive-maintainers mailing list, so please 
send any messages intended for me by email.

Neil.

dnl @synopsis AC_CXX_GCC_ABI_DEMANGLE
dnl
dnl If the compiler supports GCC C++ ABI name demangling (has header cxxabi.h 
dnl and abi::__cxa_demangle() function), define HAVE_GCC_ABI_DEMANGLE
dnl
dnl Adapted from AC_CXX_RTTI by Luc Maisonobe
dnl
dnl @version $Id$
dnl @author Neil Ferguson <address@hidden>
dnl
AC_DEFUN([AX_CXX_GCC_ABI_DEMANGLE],
[AC_CACHE_CHECK(whether the compiler supports GCC C++ ABI name demangling, 
ac_cv_cxx_gcc_abi_demangle,
[AC_LANG_SAVE
 AC_LANG_CPLUSPLUS
 AC_TRY_COMPILE([#include <typeinfo>
#include <cxxabi.h>
#include <string>

template<typename TYPE>
class A {};
],[A<int> instance;
int status = 0;
char* c_name = 0;

c_name = abi::__cxa_demangle(typeid(instance).name(), 0, 0, &status);
        
std::string name(c_name);
free(c_name);

return name == "A<int>";
],
 ac_cv_cxx_gcc_abi_demangle=yes, ac_cv_cxx_gcc_abi_demangle=no)
 AC_LANG_RESTORE
])
if test "$ac_cv_cxx_gcc_abi_demangle" = yes; then
  AC_DEFINE(HAVE_GCC_ABI_DEMANGLE,1,
            [define if the compiler supports GCC C++ ABI name demangling]) 
fi
])